/*
  Dieser Sketch ermöglicht die Anzeige der aktuellen Spritpreise auf einem OLED SSD1306 32x128 auf
  einer Modelleisenbahn. Die Größe der Anzeige ist für den MAßstab H0 sehr gut geeignet.
  Der Empfang aktueller Spritpreise erfolgt über einen ESP32 von der Webseite https://creativecommons.tankerkoenig.de/
  Hier kann nach Registierung der entsprechende (kostenlose) API-Key angefordert und die ID einer Tankstelle nach
  freier Wahl ermittelt werden.
  Die Verbindung zwischen ESP 32 und dem SSD1306 Display erfolgt über I2C.
  IO21 -> SDA
  IO22 -> SCL
 
*/
 
#include <Wire.h>
#include <WiFi.h>
#include <HTTPClient.h>
#include <Arduino_JSON.h>
#include <U8g2lib.h>
 
U8G2_SSD1306_128X32_UNIVISION_F_HW_I2C u8g2(U8G2_R3, /* reset=*/ U8X8_PIN_NONE,SCL,SDA); // R1 dreht das Display un 90 Grad zum Hochformat
//U8G2_SSD1306_128X64_NONAME_F_HW_I2C u8g2(U8G2_R1, /* reset=*/ U8X8_PIN_NONE);
 

#define U8G2_16BIT        // setzen der 16bit Verison
 
//const char *text = "Werkstatt       Reifendienst       Shop       CleanCar       ";   // Lauftext von rechts nach links
const char *text = "Geoeffnet       ";   // Lauftext von rechts nach links
 
/*
     WLAN Zugangsdaten
*/
//#include "zugangsdaten.h"
const char* ssid     = "deine_SSID";
const char* password = "dein_W-Lan_Passwort";
 
/*
     Dein persönlicher Tankerkoenig ApiKey und die abzufragende TankstellenID
*/
 
String TankerkoenigApiKey = "dein-Tankerkoenig-Api-Key";             //  kommt per Mail
String TankstellenID = "ab481fb9-4071-4984-baa1-13643f633332";       // frei wählbare TankstellenID
 
String jsonBuffer;
 
/*
     RootCA von Tankerkoenig
*/
 
const char* root_ca = \
                      "-----BEGIN CERTIFICATE-----\n" \
                      "MIIFazCCA1OgAwIBAgIRAIIQz7DSQONZRGPgu2OCiwAwDQYJKoZIhvcNAQELBQAw\n" \
                      "TzELMAkGA1UEBhMCVVMxKTAnBgNVBAoTIEludGVybmV0IFNlY3VyaXR5IFJlc2Vh\n" \
                      "cmNoIEdyb3VwMRUwEwYDVQQDEwxJU1JHIFJvb3QgWDEwHhcNMTUwNjA0MTEwNDM4\n" \
                      "WhcNMzUwNjA0MTEwNDM4WjBPMQswCQYDVQQGEwJVUzEpMCcGA1UEChMgSW50ZXJu\n" \
                      "ZXQgU2VjdXJpdHkgUmVzZWFyY2ggR3JvdXAxFTATBgNVBAMTDElTUkcgUm9vdCBY\n" \
                      "MTCCAiIwDQYJKoZIhvcNAQEBBQADggIPADCCAgoCggIBAK3oJHP0FDfzm54rVygc\n" \
                      "h77ct984kIxuPOZXoHj3dcKi/vVqbvYATyjb3miGbESTtrFj/RQSa78f0uoxmyF+\n" \
                      "0TM8ukj13Xnfs7j/EvEhmkvBioZxaUpmZmyPfjxwv60pIgbz5MDmgK7iS4+3mX6U\n" \
                      "A5/TR5d8mUgjU+g4rk8Kb4Mu0UlXjIB0ttov0DiNewNwIRt18jA8+o+u3dpjq+sW\n" \
                      "T8KOEUt+zwvo/7V3LvSye0rgTBIlDHCNAymg4VMk7BPZ7hm/ELNKjD+Jo2FR3qyH\n" \
                      "B5T0Y3HsLuJvW5iB4YlcNHlsdu87kGJ55tukmi8mxdAQ4Q7e2RCOFvu396j3x+UC\n" \
                      "B5iPNgiV5+I3lg02dZ77DnKxHZu8A/lJBdiB3QW0KtZB6awBdpUKD9jf1b0SHzUv\n" \
                      "KBds0pjBqAlkd25HN7rOrFleaJ1/ctaJxQZBKT5ZPt0m9STJEadao0xAH0ahmbWn\n" \
                      "OlFuhjuefXKnEgV4We0+UXgVCwOPjdAvBbI+e0ocS3MFEvzG6uBQE3xDk3SzynTn\n" \
                      "jh8BCNAw1FtxNrQHusEwMFxIt4I7mKZ9YIqioymCzLq9gwQbooMDQaHWBfEbwrbw\n" \
                      "qHyGO0aoSCqI3Haadr8faqU9GY/rOPNk3sgrDQoo//fb4hVC1CLQJ13hef4Y53CI\n" \
                      "rU7m2Ys6xt0nUW7/vGT1M0NPAgMBAAGjQjBAMA4GA1UdDwEB/wQEAwIBBjAPBgNV\n" \
                      "HRMBAf8EBTADAQH/MB0GA1UdDgQWBBR5tFnme7bl5AFzgAiIyBpY9umbbjANBgkq\n" \
                      "hkiG9w0BAQsFAAOCAgEAVR9YqbyyqFDQDLHYGmkgJykIrGF1XIpu+ILlaS/V9lZL\n" \
                      "ubhzEFnTIZd+50xx+7LSYK05qAvqFyFWhfFQDlnrzuBZ6brJFe+GnY+EgPbk6ZGQ\n" \
                      "3BebYhtF8GaV0nxvwuo77x/Py9auJ/GpsMiu/X1+mvoiBOv/2X/qkSsisRcOj/KK\n" \
                      "NFtY2PwByVS5uCbMiogziUwthDyC3+6WVwW6LLv3xLfHTjuCvjHIInNzktHCgKQ5\n" \
                      "ORAzI4JMPJ+GslWYHb4phowim57iaztXOoJwTdwJx4nLCgdNbOhdjsnvzqvHu7Ur\n" \
                      "TkXWStAmzOVyyghqpZXjFaH3pO3JLF+l+/+sKAIuvtd7u+Nxe5AW0wdeRlN8NwdC\n" \
                      "jNPElpzVmbUq4JUagEiuTDkHzsxHpFKVK7q4+63SM1N95R1NbdWhscdCb+ZAJzVc\n" \
                      "oyi3B43njTOQ5yOf+1CceWxG1bQVs5ZufpsMljq4Ui0/1lvh+wjChP4kqKOJ2qxq\n" \
                      "4RgqsahDYVvTH9w7jXbyLeiNdd8XM2w9U/t7y0Ff/9yi0GE44Za4rF2LN9d11TPA\n" \
                      "mRGunUHBcnWEvgJBQl9nJEiU0Zsnvgc/ubhPgXRR4Xq37Z0j4r7g1SgEEzwxA57d\n" \
                      "emyPxgcYxn/eR44/KJ4EBs+lVDR3veyJm+kXQ99b21/+jh5Xos1AnX5iItreGCc=\n" \
                      "-----END CERTIFICATE-----\n";
 
/*
    Abfragetimer, laut Nutzungsbedingungen darf die API alle 5 Minuten abgefragt werden
*/
 
void setup(void) {
 
  Serial.begin(115200);
 
  WiFi.begin(ssid, password);
  Serial.println("Connecting");
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println("");
  Serial.print("Connected to WiFi network with IP Address: ");
  Serial.println(WiFi.localIP());
 
  Serial.println("Timer auf 5 Minuten gesetzt (timerDelay variable)");
 
  delay(2000);
 
  u8g2.begin();                         // startet das SSD1306 32x128 Display
  u8g2.setFontMode(0);                  // Aktivierung das Transparentmodus
}
 
void loop(void) {
  preisanzeige();
  lauftext();
}
 
void lauftext() {
  uint32_t jetzt = millis();
  static uint32_t scrollMillis = jetzt;
  const uint32_t scrollIntervall = 60;
  static u8g2_uint_t offset;      // aktueller Offset für den Lauftext
 
  if (jetzt - scrollMillis >= scrollIntervall)
  {
    scrollMillis = jetzt;
    u8g2_uint_t x;
 
    x = offset;                                         // draw the scrolling text at current offset
    u8g2.setFont(u8g2_font_4x6_mr);                     // set the target font
    const u8g2_uint_t width = u8g2.getUTF8Width(text);  // Bechnung der Pixelbreite des Textes
    do {                                                // repeated drawing of the scrolling text...
      u8g2.drawUTF8(x, 125, text);                      // draw the scolling text
      x += width;                                       // add the pixel width of the scrolling text
    } while ( x < u8g2.getDisplayWidth() );             // draw again until the complete display is filled
 
    u8g2.sendBuffer();                          // transfer internal memory to the display
 
    offset -= 1;                              // scroll by one pixel
    if ( (u8g2_uint_t)offset < (u8g2_uint_t) - width )
      offset = 0;                               // start over again
  }
}
 
void preisanzeige() {
  static unsigned long lastTime = 0;           // 5 Minuten (300000)
  const unsigned long timerDelay = 300000UL;    // Um die ersten 5 Minuten zu überspringen
  static bool skiptimer = true;
 
  if ((millis() - lastTime) > timerDelay || skiptimer == true) {     // sende eine HTTP GET Anforderung
 
    if (WiFi.status() == WL_CONNECTED) {                             // überprüfe die WLAN-Verbindung
 
      String serverPath = "https://creativecommons.tankerkoenig.de/json/detail.php?id=" + TankstellenID + "&apikey=" + TankerkoenigApiKey;
 
      jsonBuffer = httpGETRequest(serverPath.c_str());
      Serial.println(jsonBuffer);
      JSONVar myObject = JSON.parse(jsonBuffer);
      
      if (JSON.typeof(myObject) == "undefined") {       
        Serial.println("Parsing input failed!");
        return;
      } 
 

      u8g2.clearBuffer();                         // internen Speicher löschen
      u8g2.setFont(u8g2_font_5x7_mr);             // setzen der Font-Größe
      u8g2.setCursor(0, 6 );                      // setzen des Cursers
      u8g2.print("Diesel");                       // Schreiben des Textes an die Curserposition
 
      u8g2.setFont(u8g2_font_6x12_mr);            // setzen der Font-Größe
      u8g2.setCursor(3, 18 );                     // setzen des Cursers
      u8g2.print(myObject["station"]["diesel"]);  // Schreiben des Wertes sus dem augelesenen JSON-String
 
      u8g2.setFont(u8g2_font_5x7_mr);
      u8g2.setCursor(0, 42 );
      u8g2.print("Super");
      u8g2.setFont(u8g2_font_u8glib_4_tf);
      u8g2.setCursor(21, 36 );
      u8g2.print("E5");
 
      u8g2.setFont(u8g2_font_6x12_mr);
      u8g2.setCursor(3, 54 );
      u8g2.print(myObject["station"]["e5"]);
 
      u8g2.setFont(u8g2_font_5x7_mr);
      u8g2.setCursor(0, 78 );
      u8g2.print("Super");
      u8g2.setFont(u8g2_font_u8glib_4_tf);
      u8g2.setCursor(21, 72 );
      u8g2.print("E10");
 
      u8g2.setFont(u8g2_font_6x12_mr);
      u8g2.setCursor(3, 90 );
      u8g2.print(myObject["station"]["e10"]);
 
      u8g2.sendBuffer();               //   Inhalt des internen Speicher auf das Display übertragen
 
    } else {
 
      u8g2.setFont(u8g2_font_5x7_mr);
      u8g2.setCursor(0, 6 );
      u8g2.print("Close");
 
      u8g2.sendBuffer();
 
    }
    skiptimer = false;
    lastTime = millis();
  }
 
}
 
String httpGETRequest(const char* serverName) {
  WiFiClient client;
  HTTPClient http;
 
  http.begin(serverName, root_ca);    // Domainname mit URL-Pfad oder IP-Adresse mit Pfad
 

  int httpResponseCode = http.GET();  // HTTP-POST-Anforderung senden
 
  String payload = "{}";
 
  if (httpResponseCode > 0) {
    Serial.print("HTTP Response code: ");
    Serial.println(httpResponseCode);
    payload = http.getString();
  }
  else {
    Serial.print("Error code: ");
    Serial.println(httpResponseCode);
 
  }
  // Free resources
  http.end();
 
  return payload;
}